kafka/wrapper.gradle

/*
 * Licensed to the Apache Software Foundation (ASF) under one
 * or more contributor license agreements.  See the NOTICE file
 * distributed with this work for additional information
 * regarding copyright ownership.  The ASF licenses this file
 * to you under the Apache License, Version 2.0 (the
 * "License"); you may not use this file except in compliance
 * with the License.  You may obtain a copy of the License at
 *
 *   http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

// This file contains tasks for the gradle wrapper generation.

// Ensure the wrapper script is generated based on the version defined in the project
// and not the version installed on the machine running the task.
// Read more about the wrapper here: https://docs.gradle.org/current/userguide/gradle_wrapper.html
wrapper {
    gradleVersion = versions.gradle
}

// Custom task to inject support for downloading the gradle wrapper jar if it doesn't exist.
// This allows us to avoid checking in the jar to our repository.
task bootstrapWrapper() {
    // In the doLast block so this runs when the task is called and not during project configuration.
    doLast {
        def wrapperBasePath = "\$APP_HOME/gradle/wrapper"
        def wrapperJarPath = wrapperBasePath + "/gradle-wrapper.jar"

        // Leverages the wrapper jar checked into the gradle project on github because the jar isn't
        // available elsewhere. Using raw.githubusercontent.com instead of github.com because
        // github.com servers deprecated TLSv1/TLSv1.1 support some time ago, so older versions
        // of curl (built against OpenSSL library that doesn't support TLSv1.2) would fail to
        // fetch the jar.
        // The jar is fetched from a pinned commit rather than the release tag: a release tag contains
        // the bootstrap jar Gradle uses to build itself, which may be from the previous version and then
        // doesn't match the published wrapper checksum; for more details see gradle/wrapper/README.md
        // and https://issues.apache.org/jira/browse/KAFKA-21299
        String wrapperJarCommit = "dcc5ee0ec88270575344e6afd490f96d96f84ab3"
        String wrapperChecksum = "3b8a25775a69158b5ad2b1d17a80a88dc7b40a352a73eb27d06c612a7ce68e98"
        def wrapperJarUrl = "https://raw.githubusercontent.com/gradle/gradle/$wrapperJarCommit/gradle/wrapper/gradle-wrapper.jar"

        def bootstrapString = """
      # Loop in case we encounter an error.
      REQUIRED_WRAPPER_JAR_CHECKSUM="$wrapperChecksum"
      for attempt in 1 2 3; do
        if [ ! -e "$wrapperJarPath" ]; then
          if ! curl -s -S --retry 3 -L -o "$wrapperJarPath" "$wrapperJarUrl"; then
            rm -f "$wrapperJarPath"
            # Pause for a bit before looping in case the server throttled us.
            sleep 5
            continue
          fi
        else
          # Verify checksum of existing wrapper JAR. 
          # This prevents developers from running into incompatibility issues when using an outdated wrapper JAR after a Gradle upgrade.
          # Use sha256sum or shasum, whichever is available.
          if command -v sha256sum >/dev/null 2>&1; then
            LOCAL_WRAPPER_JAR_CHECKSUM=\$(sha256sum "$wrapperJarPath" | awk '{print \$1}')
          elif command -v shasum >/dev/null 2>&1; then
            LOCAL_WRAPPER_JAR_CHECKSUM=\$(shasum -a 256 "$wrapperJarPath" | awk '{print \$1}')
          else
            # If no checksum tool is found, this verification is skipped .
            warn "Cannot find sha256sum or shasum to verify wrapper JAR."
            break
          fi

          # If the local checksum does not match the required checksum, delete the JAR to force re-download.
          if [ "\$LOCAL_WRAPPER_JAR_CHECKSUM" != "\$REQUIRED_WRAPPER_JAR_CHECKSUM" ] ; then
            rm -f "$wrapperJarPath"
          else
            break
          fi
        fi
      done
      """.stripIndent()

        String putBootstrapStringAbove = "# Add default JVM options here. You can also use JAVA_OPTS and GRADLE_OPTS to pass JVM options to this script."

        def wrapperScript = wrapper.scriptFile
        def wrapperLines = wrapperScript.readLines()
        wrapperScript.withPrintWriter { out ->
            def bootstrapWritten = false
            wrapperLines.each { line ->
                // Print the wrapper bootstrap before the first usage of the wrapper jar.
                if (!bootstrapWritten && line.contains(putBootstrapStringAbove)) {
                    out.println(bootstrapString)
                    bootstrapWritten = true
                }
                out.print(line)
                out.println()
            }
        }
    }
}
wrapper.finalizedBy bootstrapWrapper

// Remove the generated batch file since we don't test building in the Windows environment.
task removeWindowsScript(type: Delete) {
    delete "$rootDir/gradlew.bat"
}
wrapper.finalizedBy removeWindowsScript